joe-3.1jupp31.tgz (die zweite Klappeā€¦)
[alioth/jupp.git] / configure.ac
1 # $MirOS: contrib/code/jupp/configure.ac,v 1.56 2017/08/09 01:00:22 tg Exp $
2 #-
3 # Process this file with autoconf to produce a configure script.
4
5 # We need AC_PROG_EGREP
6 AC_PREREQ(2.54)
7
8 #### Here's the only place where to change version number ####
9 AC_INIT(joe, 3.1jupp31)
10 #### But see main.c for the Copyright (c) owner and year! ####
11 AC_CONFIG_SRCDIR([b.c])
12
13 AC_CANONICAL_BUILD
14 AC_CANONICAL_HOST
15 AC_CANONICAL_TARGET
16
17 # Init automake
18 AM_INIT_AUTOMAKE
19 AM_MAINTAINER_MODE
20 AM_CONFIG_HEADER(autoconf.h)
21
22 # Checks for programs.
23 AC_PROG_CC
24 AC_PROG_CPP
25 AC_PROG_EGREP
26 AC_PROG_INSTALL
27 AC_PROG_LN_S
28
29 case $host in
30 *-*-minix*)
31         CPPFLAGS="$CPPFLAGS -D_POSIX_SOURCE -D_POSIX_1_SOURCE=2 -D_MINIX"
32         ;;
33 *-gnu*)
34         CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
35         ;;
36 esac
37
38 case $host in
39 *-*-mirbsd* | *-*-openbsd*)
40         AC_DEFINE(HAVE_GCC_ATTRIBUTE_BOUNDED, 1, [Define if GCC has Anil's bounds checker])
41         ;;
42 esac
43
44
45 # Checks for libraries.
46
47 search_libs_selinux="selinux"
48 search_libs_snprintf="snprintf db"
49 search_libs_term=""
50 search_libs_util="util"
51
52 AC_ARG_ENABLE(curses,
53 [  --disable-curses        disable use of curses library],
54         curses=$enableval, curses=yes)
55 test x"$curses" = x"yes" && \
56     search_libs_term="$search_libs_term tinfo ncurses curses"
57
58 AC_ARG_ENABLE(termcap,
59 [  --disable-termcap       disable use of termcap library],
60         termcap=$enableval, termcap=yes)
61 test x"$termcap" = x"yes" && \
62     search_libs_term="$search_libs_term termcap"
63
64 AC_ARG_ENABLE([search_libs],
65 [  --disable-search-libs   do not search in any external libraries],
66         search_libs=$enableval, search_libs=yes)
67
68 if test x"$search_libs" = x"no"; then
69         search_libs_selinux=""
70         search_libs_snprintf=""
71         search_libs_term=""
72         search_libs_util=""
73 fi
74
75 AC_SEARCH_LIBS(openpty, $search_libs_util, AC_DEFINE_UNQUOTED(HAVE_OPENPTY, 1, [If we have BSD function openpty()]))
76 AC_SEARCH_LIBS(login_tty, $search_libs_util, AC_DEFINE_UNQUOTED(HAVE_LOGIN_TTY, 1, [If we have BSD function login_tty()]))
77 AC_SEARCH_LIBS(tgetflag, $search_libs_term, AC_DEFINE_UNQUOTED(TERMINFO, 1, [If we have newer terminfo/termcap capabilities]))
78 AC_SEARCH_LIBS(snprintf, $search_libs_snprintf, AC_DEFINE_UNQUOTED(HAVE_SNPRINTF, 1, [If we have snprintf]))
79 AC_SEARCH_LIBS(is_selinux_enabled, $search_libs_selinux, AC_DEFINE_UNQUOTED(HAVE_SELINUX_FUN, 1, [We have SELinux functions]))
80
81
82 # other conditionals
83
84 AC_ARG_ENABLE([getpwnam],
85 [  --disable-getpwnam      disable use of getpwnam function],
86         getpwnam=$enableval, getpwnam=yes)
87 test x"$getpwnam" = x"no" && CPPFLAGS="$CPPFLAGS -DJOE_NOPWNAM"
88
89 AC_ARG_ENABLE([termidx],
90 [  --disable-termidx       do not build the termidx binary],
91         termidx=$enableval, termidx=yes)
92 AM_CONDITIONAL([WANT_TERMIDX], [test x"$termidx" != x"no"])
93
94 AC_ARG_ENABLE([sysconfjoesubdir],
95 [  --enable-sysconfjoesubdir=/joe  (default value)],
96         [sysconfjoesubdir=$enableval], [sysconfjoesubdir=yes])
97 if test x"$sysconfjoesubdir" = x"yes"; then
98         sysconfjoesubdir=/joe
99 elif test x"$sysconfjoesubdir" = x"no"; then
100         sysconfjoesubdir=
101 fi
102 AC_SUBST(sysconfjoesubdir)
103
104 AC_ARG_ENABLE([win32reloc],
105 [  --enable-win32reloc     enable win32 self-relocation],
106         [win32reloc=$enableval], [win32reloc=no])
107 AM_CONDITIONAL([JUPP_WIN32RELOC], [test x"$win32reloc" = x"yes"])
108 if test x"$win32reloc" = x"yes"; then
109         joeinitfile='\\fBjoerc\\fR in the same directory as the binary resides in'
110         joeinitcopy='which resides in the same directory as the binary'
111         joeresides='C:\\eProgramme\\ejupp32\\ejoe.exe'
112         jrcbefore=''
113         jrcafter=' in the same directory as the binary'
114 elif test x"$win32reloc" = x"old"; then
115         joeinitfile='\\fBc:/windows/system32/joe/joerc\\fR'
116         joeinitcopy='which resides in \\fBc:/windows/system32/joe/joerc\\fR'
117         joeresides='c:/windows/system32/joe.exe'
118         jrcbefore='c:/windows/system32/joe/'
119         jrcafter=''
120 else
121         joeinitfile='usually \\fB'$sysconfdir$sysconfjoesubdir'/joerc\\fR'
122         joeinitcopy='which normally resides in \\fB'$sysconfdir$sysconfjoesubdir'/joerc\\fR'
123         joeresides=$bindir'/joe'
124         jrcbefore=$sysconfdir$sysconfjoesubdir/
125         jrcafter=''
126 fi
127 AC_SUBST(joeinitfile)
128 AC_SUBST(joeinitcopy)
129 AC_SUBST(joeresides)
130 AC_SUBST(jrcbefore)
131 AC_SUBST(jrcafter)
132
133
134 # Checks for header files.
135
136 AC_CHECK_HEADERS([ \
137         sys/dirent.h sys/ioctl.h sys/param.h sys/stat.h sys/termio.h \
138         sys/termios.h sys/time.h sys/types.h sys/wait.h errno.h fcntl.h \
139         langinfo.h limits.h locale.h paths.h pty.h pwd.h sgtty.h signal.h \
140         stdlib.h string.h termio.h termios.h time.h unistd.h util.h utime.h \
141         utmp.h bsd/string.h selinux/context.h selinux/selinux.h \
142 ])
143 AC_HEADER_DIRENT
144 AC_SYS_POSIX_TERMIOS
145 if test "$ac_cv_sys_posix_termios" = "yes"; then
146         AC_DEFINE(HAVE_POSIX_TERMIOS, 1, [We have <termios.h> and maybe <sys/termios.h>])
147 else
148         if test "$ac_cv_header_termio_h" = "yes" -a "$ac_cvs_header_sys_termio_h" = "yes" ]; then
149                 AC_DEFINE(HAVE_SYSV_TERMIO, 1, [We have <termio.h> and <sys/termio.h>])
150         fi
151 fi
152 AC_HEADER_TIOCGWINSZ
153
154 AC_HEADER_TIME
155
156 if test "$ac_cv_header_selinux_selinux_h" = "yes" -a "$ac_cv_header_selinux_context_h" = "yes" ; then
157         echo "Enabling SELinux context copying!"
158         AC_DEFINE(HAVE_SELINUX_HDR, 1, [We have SELinux headers])
159 fi
160
161 # Checks for typedefs, structures, and compiler characteristics.
162
163 AC_C_PROTOTYPES
164 AC_C_CONST
165 AC_SYS_LARGEFILE
166 if test "$cross_compiling" = "yes" ; then
167         AC_MSG_WARN(cross compiling so assuming defaults for most 32 bit machines)
168 fi
169 AC_CHECK_SIZEOF(char, 1)
170 AC_CHECK_SIZEOF(short, 2)
171 AC_CHECK_SIZEOF(int, 4)
172 AC_CHECK_SIZEOF(long, 4)
173 AC_CHECK_SIZEOF(void *, 4)
174 AC_CHECK_SIZEOF(long long, 8)
175 AC_CHECK_SIZEOF(off_t, 8)
176 AC_CHECK_TYPE([sighandler_t],
177         [AC_DEFINE([HAVE_SIGHANDLER_T], 1, [Define if you have the `sighandler_t' type.])],
178         ,
179         [/* if you have signal.h header, include it */
180 #ifdef HAVE_SIGNAL_H
181 #include <signal.h>
182 #endif])
183
184 # Checks for library functions.
185
186 AC_PROG_GCC_TRADITIONAL
187 AC_FUNC_FSEEKO
188 AC_FUNC_LSTAT
189 joe_SETPGRP
190 AC_TYPE_PID_T
191 AC_TYPE_SIZE_T
192 AC_CHECK_TYPE([ssize_t], [], [
193         AC_DEFINE([ssize_t], [int], [Define to `int' if <sys/types.h> does not define.])
194         ], [])
195 AC_TYPE_SIGNAL
196 AC_FUNC_STAT
197 AC_CHECK_FUNCS([getcwd getwd])
198 if test x"$ac_cv_func_getcwd" != xyes; then
199         if test x"$ac_cv_func_getwd" != xyes; then
200                 AC_MSG_ERROR([don't know how to get current working directory])
201         fi
202 fi
203 AC_CHECK_FUNCS([isblank])
204 if test x"$ac_cv_func_isblank" = xyes; then
205         joe_ISBLANK
206 fi
207 AC_CHECK_FUNCS([alarm mkdir mkstemp putenv setlocale strchr strdup utime setpgid])
208 AC_CHECK_FUNCS([setitimer sigaction sigvec siginterrupt sigprocmask isatty])
209 AC_CHECK_FUNCS([strlcpy strlcat nl_langinfo get_current_dir_name ctime popen])
210
211 AC_CHECK_DECLS([strlcpy, strlcat, popen])
212 AC_CHECK_DECLS([ctime], [], [], [AC_INCLUDES_DEFAULT
213 #ifdef TIME_WITH_SYS_TIME
214 # include <sys/time.h>
215 # include <time.h>
216 #else
217 # ifdef HAVE_SYS_TIME_H
218 #  include <sys/time.h>
219 # else
220 #  include <time.h>
221 # endif
222 #endif
223 ])
224
225 joe_REINSTALL_SIGHANDLERS
226
227 AH_VERBATIM([_PARAMS],[/* Check to see if we can use strict prototypes */
228 #ifndef PARAMS
229 #  ifdef PROTOTYPES
230 #    define PARAMS(protos) protos
231 #  else
232 #    define PARAMS(protos) ()
233 #  endif
234 #endif])
235
236 # Check for programs..
237 AC_CHECK_PROG(SPELL,aspell,aspell,ispell)
238
239 AC_CONFIG_FILES([Makefile joerc jmacsrc jstarrc rjoerc jpicorc
240 syntax/c.jsf syntax/perl.jsf syntax/verilog.jsf syntax/sh.jsf syntax/python.jsf
241 syntax/conf.jsf syntax/php.jsf syntax/mail.jsf syntax/pascal.jsf syntax/html.jsf
242 syntax/vhdl.jsf syntax/fortran.jsf syntax/java.jsf syntax/xml.jsf syntax/tcl.jsf
243 charmaps/klingon syntax/lisp.jsf syntax/csh.jsf syntax/mason.jsf syntax/diff.jsf
244 syntax/asm.jsf syntax/tex.jsf])
245 AC_OUTPUT